home *** CD-ROM | disk | FTP | other *** search
/ Collection of Tools & Utilities / Collection of Tools and Utilities.iso / comm / mnpc12.zip / TIMER.ASM < prev   
Assembly Source File  |  1988-01-30  |  5KB  |  192 lines
  1.     title    timers.. timerins, timerrem, and timerint
  2.     page    60,132
  3. ;==============================================================================
  4. ;
  5. ;                   The Microcom MNP Library
  6. ;                    (Microsoft C Version)
  7. ; 
  8. ;------------------------------------------------------------------------------
  9. ;
  10. ;    timerins -- timer install routine
  11. ;
  12. ;    synopsis: timerins();
  13. ;
  14. ;------------------------------------------------------------------------------
  15. ;
  16. ;    timerrem -- timer remove routine
  17. ;
  18. ;    synopsis: timerrem();
  19. ;
  20. ;------------------------------------------------------------------------------
  21. ;
  22. ;    timerint -- timer interrupt routine (invoked on timer tick)
  23. ;
  24. ;------------------------------------------------------------------------------
  25. ;
  26. ;    Modification History
  27. ;
  28. ;    10/29/87 - timerint allowed to run with interrupts enabled..gp
  29. ;
  30. ;==============================================================================
  31.  
  32. _data    segment word public 'DATA'
  33. _data   ends
  34. dgroup  group    _data
  35.  
  36. _data   segment
  37. old_t_vct    label    dword        ; old timer vector contents
  38. old_bx        dw    0        ; base
  39. old_es        dw    0        ; segment
  40. timer_active    db    0        ; timer active flag
  41. tick        db    18        ; clock tick count
  42.  
  43. timer_no  equ    6            ; number of timers in table
  44.  
  45.     extrn    _g_tm:word    ; start of timers 
  46.  
  47. _data    ends
  48.  
  49. _text    segment byte public 'CODE'
  50.     assume    cs:_text,ds:dgroup
  51.  
  52.     public    _timerins,_timerrem
  53.     public    cdsg
  54.     public     _timer_int
  55.  
  56.  
  57. ; Data in code segment
  58. cdsg    dw    0
  59.  
  60.     page
  61. ;PUBLIC***********************************************************************
  62. ;
  63. ;    timerins - timer installation routine
  64. ;
  65. ;*****************************************************************************
  66.  
  67. _timerins proc near
  68.  
  69.     push    bp
  70.     push    es                ; save es and ds
  71.     push    ds
  72.  
  73. ; Check to be sure that the timer interrupt handler is not already
  74. ; installed.  Do nothing in this case.
  75.     cmp    timer_active,1        ; already installed?
  76.     je    tin9                ; yes-go return
  77.  
  78. ; Initialize
  79.     mov    timer_active,1        ; set timer active flag
  80.     mov    cs:cdsg,ds        ; save data segment
  81.  
  82. ; Save current interrupt vector contents then install our own handler.
  83.     mov    ah,35h            ; get vector request
  84.     mov    al,1ch            ; we want the timer one
  85.     int    21h                ; int to DOS
  86.     mov    old_bx,bx            ; save vector contents
  87.     mov    old_es,es
  88.     mov    dx,offset _timer_int    ; point to our handler
  89.     mov    ax,cs            ; be sure ds is right
  90.     mov    ds,ax
  91.     mov    ah,25h            ; set vector request
  92.     mov    al,1ch            ; we want the timer one
  93.     int    21h                ; int to DOS
  94.  
  95. ; Return
  96. tin9:
  97.     pop    ds                ; restore data segment
  98.     pop    es                ; restore es
  99.     pop    bp
  100.     ret
  101.  
  102. _timerins endp
  103.      page
  104. ;PUBLIC***********************************************************************
  105. ;
  106. ;    timerrem - timer removal subroutine
  107. ;
  108. ;*****************************************************************************
  109.  
  110. _timerrem proc near
  111.  
  112.     push    bp
  113. ; Check to be sure that the timer interrupt handler is already
  114. ; installed.  Do nothing if not.
  115.     cmp    timer_active,1        ; installed?
  116.     jne    tir9                ; no-go return
  117.  
  118. ; Recover old vector contents and put them back.
  119.     push    ds                ; save ds register
  120.     mov    ah,25h            ; set vector request
  121.     mov    al,1ch            ; we want the timer one
  122.     mov    dx,old_bx            ; recover old vector
  123.     mov    ds,old_es
  124.     int    21h                ; int to DOS
  125.     pop    ds                ; restore ds register
  126.     mov    timer_active,0        ; reset timer active flag
  127.  
  128. ; Return
  129. tir9:
  130.     pop    bp
  131.     ret
  132.  
  133. _timerrem endp
  134.     page
  135. ;*****************************************************************************
  136. ;
  137. ;    timerint - timer interrupt routine
  138. ;
  139. ;*****************************************************************************
  140.  
  141. _timer_int proc far
  142.  
  143. ; Initialize
  144.     push    ds                ; save registers
  145.     mov    ds,cs:cdsg        ; enable data addressability
  146.  
  147. ; Re-enable interrupts
  148. ;####    sti
  149.  
  150. ; When a clock interrupt occurs, decrement the second ticker.  If the
  151. ; ticker goes to zero, count down the second-based timers.
  152. t1:
  153.     dec    tick                ; decrement ticker
  154.     jnz    tiret            ; go on if not zero
  155.  
  156. ; Pass through second-based timers and decrement any that are not already
  157. ; zero.  Zero can mean either 'elapsed' or 'inactive'.
  158. ti1:
  159.     mov    tick,18             ; reset ticker
  160.  
  161.     push    bx                ; save registers
  162.     push    cx
  163.     mov     bx,offset _g_tm
  164. ;    mov    bx,offset timers    ; point to list of timers
  165.     mov    cx,timer_no        ; do for each timer
  166.  
  167. ti3:
  168.     cmp    word ptr [bx],0     ; active?
  169.     je    ti4                ; no-go on
  170.     dec    word ptr [bx]        ; yes-count it down
  171.  
  172. ti4:
  173.     add    bx,2                ; advance to next timer
  174.     loop    ti3                ; and try again
  175.  
  176.     pop    cx                ; restore registers
  177.     pop    bx                ; and go on
  178.  
  179. tiret:
  180.     cli                    ;  disable interrupts before call
  181.     pushf                ; this is to simulate an int instruction
  182.     call    old_t_vct            ; inter-segment indirect call
  183.  
  184.     pop    ds
  185.     sti                    ; re-enable interrupts
  186.     iret                    ; and return from interrupt
  187.  
  188. _timer_int endp
  189.  
  190. _text    ends
  191.     end
  192.